| Calculate the date a week later |
Create a formula date type field which displays the date that's a week later than the value in the Start Date field. |
Dates |
[Start Date] + Days (7) |
Take the value in the Start Date field and add seven days to it. |
|
Date |
|
| I need a formula that returns the reporting period month. Any date after the 18th of the month will return a reporting period of the following month |
|
Dates |
If(Day([Date]) <= 18, Case((Month ([Date]))-1, 1,"January",2,"February",3,"March",4,"April",5,"May",6,"June",7,"July",8,"August",9,"September",10,"October",11,"November",12,"December"), Case(Month ([Date]), 1,"January",2,"February",3,"March",4,"April",5,"May",6,"June",7,"July",8,"August",9,"September",10,"October",11,"November",12,"December"))
|
If the day of the month entered into the [Date] Field is less than or equal to 18, then subtract one from the month of the date field and based on the month number return the matching name of month.
Else if the day of the month entered into the [date] field is greater than 18 then return the month of the [date field], and based on the month number return the matching month name.
|
|
Date |
|
| Calculate the number of weeks into the year a date is |
In Excel I can use the WeekNum function to calculate how many weeks into the year a particular date is. How do I do this in QuickBase? |
Dates |
Int(DayofYear([datefield])/7+1)
|
Find the day of the year that the date field is (in other words how many days into the year the date is). Then divide by seven to get the number of weeks into the year. Add one. Then show the integer only (in other words, leave off any fractional values that follow the decimal point). |
There is no week 0, so the first week is 1. That's why you add 1.
This formulas returns the "Absolute Week Number" which counts weeks starting from January 1st, no matter what day of the week it is. In other words, Jan 1st through 7th is always week one. If Jan 1st is a Tuesday, than each week of the year will be Tuesday through Monday and tallied accordingly. |
Numeric |
If you'd like to calculate the week number, but specify that each week begin on a Sunday (in other words, week one always ends on the first Saturday of January and following weeks are tallied based on that premise) try this formula instead:
Int(DayOfYear(Days(DayOfWeek(FirstDayOfYear([MyDate])))
+ [MyDate])/7+1) |
| Dynamically adjusting successor start dates from predecessor changes |
Related to Project Management application |
Calculation |
If( ([Status]<>"Completed"),WeekdayAdd([Start], [Duration]),
ToWorkDate([Actual Finish Date]) )
The predecessor field (under properties) needs to be changed from formula builder to Type-In. |
If the task is not completed, it calculates the expected end date (by adding the amount of time it will take to when it starts), and if the task is completed, then it uses the date that it was actually finished, as entered by the user completing the task. |
|
Workdate |
|
| Calculate a task's finish date, based on the start date and number entered in the Estimated # of Days field. |
Adding a numeric value (Estimated # of Days) to a date value doesn't work. |
Type Conversion |
[Actual Start Date]+ Days([Estimated # of days]) |
Convert the number in the Estimated # of days field into a duration that represents a number of days and add it to the Actual Start Date. |
The Days() function converts the numeric value into a Duration value. |
Date |
|
| Need to see the day of the week for a date. |
If only the day of the week is needed and not the whole date, then this formula can be used. |
Dates |
Case(DayOfWeek([YourDateFieldHere]), 0, "Sunday",
1, "Monday",
2, "Tuesday",
3, "Wednesday",
4, "Thursday",
5, "Friday",
6, "Saturday") |
Note that the DayofWeek() takes a date, and not a workdate, so if the field is a workdate field, then you must convert it to date using ToDate(). |
|
Text |
|
| Find duration between two dates |
Find the length of time between the date a record is created and the date the record's marked complete. |
Dates |
ToDays([Actual Finish Date] - ToDate([Date Created])) |
Take the value in the Date Created field (Date / Time type field) and convert it to a date value. Then subtract that date from the Actual Finish Date. Convert the resulting duration to a number of days. |
You must convert the this formula result to days to make it data type numeric.
If your result field type if formula-duration instead try:
[Actual Finish Date] - ToDate([Date Created]) |
Numeric |
If both dates live in Date type fields you can use a much simpler formula: [Actual Finish Date] - [Start Date] |
| Find duration between a date and today |
Find the length of time between a date and the current day's date (today). This is handy for finding the number of days until a planned finish date, for example. |
Dates |
ToDays([Planned Finish Date] - Today()) |
Subtract today's date from the Planned Finish Date. |
If you want to display the result in a Duration type field instead, then you don't need the ToDays() function. Use this formula instead:
[Planned Finish Date] - Today() |
Numeric |
If your result field is a Duration type field, try this formula instead: [Planned Finish Date] - Today() |
| Convert dates to European format |
Is there any way to change the default date format in my Date Identified field to the european DD/MM/YYYY? |
Dates |
Left(NotLeft(ToText([Date Identified]),"-"),"-")& "-" &
Case(Left(ToText([Date Identified]),2),
"01","Jan","02","Feb","03","Mar","04","Apr","05",
"May","06","Jun","07","Jul","08","Aug","09","Sep",
"10","Oct","11","Nov","12","Dec")& "-"
& Right(ToText([Date Identified]),"-") |
|
You can't do this within a date field. You must create a formula - text type field to display dates in this format. |
Text |
|
| Calculate a date 1 year ago |
Return a date that's exactly one year before the value in an existing date field (named Date). |
Dates |
AdjustYear([Date],-1) |
Take the value in the Date field and subract one from the year. |
Note that you can use the AdjustYear() function to go forward in time too. |
Date |
|
| Extract day and month from a date |
You want to display only the day and month without the year. |
Dates |
Left(ToText([Date]),5) |
Convert the value in the Date field to a text type value. Then extract the leftmost 5 characters. |
If the value in the Date field is 07-08-1967, this formula returns 07-08. Note that this formula produces a text type value. |
Text |
|
| Calculate the date three business days later |
Create a formula date type field which displays the date that's three business days after the value in the Start Date field. |
Dates |
WeekdayAdd([Start Date],3) |
Take the value in the Start Date field and add three weekdays to it. |
This formula works when the value in the Start Date field is a date type value. If the Start Date field is a Workdate type field, do one of the following:
- use the ToDate() conversion function: ToDate(WeekdayAdd([Start],3))
or
- Create a Formula Workdate type field to store results instead of a Formula Date type field. |
Date |
|
| Highlight overdue tasks in pink |
You want to color code rows based on the Due Date field. |
Row Colorization |
if ([Due Date] < Today(), "pink", "") |
If the value in the Due Date field is less than (e.g. earlier than) today, then color the row pink, otherwise, don't color it. |
|
none - view builder formula |
|
| Calculate the number of months until a payoff date |
|
Dates |
((Year([Payoff Date]) - Year(Today()) )* 12) + (Month([Payoff Date]) - Month(Today()) ) |
Take this year (that today's date occurs in) and subtract it from the year listed in the Payoff Date field. Then multiply that number of years by 12 (to get months). Take that number of months and add it to the number of months that results from subtracting this month from the month listed in the Payoff date field. |
You're really calculating the number of months in two steps. On the left side of the plus sign, you're figuring out how many years until the payoff date and converting that into months. On the right side of the plus sign, you're figuring out the difference in months. The plus sign then adds those figures together. |
Numeric |
|
| Calculate an expiration date |
Calculate an expiration date based on a contract start date and a period of months. |
Dates |
AdjustMonth([Start Contract Date], [Contract Length in Months]) |
Take the date in the Start Contract Date Field and add the number of months in the Contract Length field. |
Contract Length is a numeric field which lists a number of months |
Date |
|
| Create a view that contains records for the "current month" only |
|
Conditional (If - Then) |
If(Month([Date])=Month(Today()), "Current Month","Not Current Month") |
If the month in the Date field is the same month as today, then display the text "Current Month" otherwise display the text "Not Current Month. |
Use this formula to create a view. You can feature the text field in the view to see which records say "Current Month." You can also use this custom formula field in the view's criteria. In other words, design the view so that you only see those records that occur in the Current Month. Read more about using custom columns in views here: https://www.quickbase.com/help/custom_column_in_view.html
See also: https://www.quickbase.com/db/6mztyxu8?a=dr&r=n8&rl=xgi |
Text |
|
| Find records that occur before the current month |
|
Dates |
[Start Date]< FirstDayOfMonth(Today()) |
Start date is before the first day of the month in which today occurs |
|
Checkbox |
|
| Set status based on whether or not another field is checked. |
Automatically set the Status field to "Complete," when a staff member enters a date in the Completion Date field. |
Conditional (If - Then) |
Design the Status field using the following formula:
if(isnull([Completion Date]), "Pending", "Complete") |
If no one's entered a value in the Completion Date field (in other words that field is null) then display the word "Pending." If not, display the word "Complete." |
|
Text |
|
| Calculate the number of months that the date of last payment is past due |
I want to show the number of months overdue, but include complete months only, leaving off possible partial months. |
Dates |
Floor ( ToDays (Today() - [Date of Last Payment]) / 30) |
Subtract the Date of Last Payment from Today. ToDays converts that duration to a numeric value of days. Divide that number by 30 and return the the number of complete months that have passed. |
Floor() function returns the largest integer that's less than the number in question. For example, Floor(2.4) would return 2. Likewise, Floor (2.7) would return 2. |
Numeric |
|
| Calculate project duration if project is completed |
If [Status] is "Completed", figure the duration based on [End Date], but if the status is anything else, figure duration on today's date. |
Conditional (If - Then) |
IF(([Status]="Completed"),[End Date]-[Start Date],Today()- [Start Date]) |
If the value in the Status field is "Completed" then show the result of subtracting the Start Date from the End Date. Otherwise, show the result of subtracting the Start Date from today. |
|
Duration |
|
| View records from the previous week only |
How do I create a view that on any day of the week I can view records dated from the previous week? |
Dates |
If([Date]>FirstDayOfWeek(Today()-Days(7)) and
[Date]< LastDayOfWeek(Today()-Days(7)),
true,
false) |
Subtract 7 days from today. Take the resulting date (let's call it "one week ago date") and calculate the first day of its week. If that is greater than the value in the Date field and If that date is less than the last day of the week in which "one week ago date" falls, the result is true (checkbox is on) otherwise the result is false (checkbox is off). |
You can create a formula - checkbox type field to hold this formula or just use the formula within the report (view) builder page. In this case, also select checkbox as the type, then within the Matching Criteria section, specify that <custom column> is yes (type in the word yes). |
Checkbox |
|
| Calculate the date of the last Friday before a Due Date |
In each record, I want to calculate what date is the Friday that comes before each Due Date |
Dates |
PrevDayOfWeek([Date Due], 5) |
Take the value in the date due field and figure out the date of the previous week's Friday. |
5 represents Friday within the PrevDayOfWeek() function. |
Date |
|
| Find the duration between two date fields of different types |
Actual Finish is a date field and Actual Start is a workdate field. How can I find the duration between them without getting a type mismatch error? |
Type Conversion |
[Actual Finish]-ToDate([Actual Start]) |
Convert the value in the Actual Start field to a date type value. Then subtract that date from the Actual Finish date |
|
Duration |
|
Function Details